Landslide Due to an Earthquake

Problem Statement

Example Application

The project file for this example may be viewed/run in FLAC2D.[1] The main data file used is shown at the end of this example.

How To Read and Use Examples

This model simulates a potential landslide happening on a generic convex slope due to an earthquake. The seismic loading history corresponds to the 1989 Loma Prieta earthquake (M6.9), and it is applied in the form of horizontal acceleration at the bottom boundary of the model.[2]

FLAC2D Model

The model is provided within project “Landslide2d” and its geometry is shown in Figure 1. The horizontal extent of the model is 300 m, the height on left is 50 m and on the right side is ~27.4 m. Model geometry is generated by using a table of elevations, “Elevations.tab”, provided with the project. The model consists of two layers: a base rock which is simulated as an elastic medium, and soil deposited on the top part and simulated as material with softening behavior.

../../../../../_images/landslide2d-model.png

Figure 1: Model geometry and remeshing boundary.

Figure 1 shows the remeshing boundaries in red which are set to be smaller than the model extent. This is done to fully retain the free-field boundary conditions at the left-most and right-most extents of the model as remeshing may affect fields at these locations due to data interpolation. At the same, it is important to ensure that the model has sufficient extent so that the deformations at the vertical remeshing boundaries are very small. Note that the remeshing boundaries are assigned in this model by using the range logic and existing face groups (Sketch is not used).

Initially the model is set to be fully elastic and cycled to equilibrium to establish the in-situ stresses. This is modeled within datafile “initial.dat”. After this, soil is reassigned to strain-softening model, and the model is brought to a static equilibrium again (first part of data file). The strain-softening material behavior is provided by the table “ssTable”.

In the final part of the model, the dynamic analysis is activated and x-acceleration is applied at the bottom boundary using table “Loma-Prieta.txt”. The acceleration record is shown in Figure 2. The model uses free-field boundary conditions to prevent any wave reflections from the sides of the model. Maxwell damping is used with a target damping ratio of 3% in the range of 0.35 to 25 Hz.

The model is run in large-strain mode for 30 seconds. The slope starts visibly failing as acceleration reaches its peak value and then continues failing forming multiple shearing bands. During the simulations the model is remeshed several times as zones significantly deform due to slope failure. Without automatic remeshing, the model would stop cycling after ~9 seconds with illegal geometry error.

../../../../../_images/landslide2d-acceleration.png

Figure 2: Acceleration history.

Figure 3 shows failed slope shape at 30sec. The squares at the top surface of the model designate history locations at which horizontal displacements are tracked. The displacement histories shown in Figure 4 reveal that after the slope fails during the first 20 seconds of the simulation, it stabilizes and remains stable afterwards. Both Figure 3 and Figure 4 show significant movement at the surface top, reaching almost 20 m of horizontal displacement at some of the locations.

../../../../../_images/landslide2d-shear-strain.png

Figure 3: Failed slope after 30sec and the shear bands formed in the model.

../../../../../_images/landslide2d-histories.png

Figure 4: Horizontal displacement histories at the top boundary of the model. Colors correspond to the locations on Figure 2.

All the datafiles for the model are provided within the project.

Data Files

model restore 'initial'

; define cohesion - plastic strain table
fish define ssTable
    table.x('ssTable',1) = 0.0
    table.y('ssTable',1) = 44.e3
    table.x('ssTable',2) = 0.1155
    table.y('ssTable',2) = 24.44e3
    table.x('ssTable',3) = 100.0    
    table.y('ssTable',3) = 24.44e3
end
[ssTable]

; set Soil to strain-softening model
zone cmodel assign strain-softening range group 'Soil'
zone property density 1800 range group 'Soil'
zone property young 4e7 poisson 0.35 range group 'Soil'
zone property cohesion 70e3 range group 'Soil'
zone property table-cohesion 'ssTable'

; solve model after changing soil to strain-softening
model solve convergence 1

; initialize dynamic analysis
model dynamic active on
model large-strain on

; read rock outcrop acceleration time history
table 'InputMotion' import 'Loma-Prieta.txt'
zone face apply acceleration-x 9.81 table 'InputMotion' ...
                  time dynamic range group 'BaseBottom'

; use dynamic free-field
zone dynamic free-field
zone gridpoint initialize displacement 0 0

; record histories
model history dynamic time-total
model history timestep
zone history name 'accl_bottom' acceleration-x position 0.0,-50.0
zone history name 'disp-x_1' displacement-x position 0.0, -1.35
zone history name 'disp-x_2' displacement-x position 20.0,-6.1
zone history name 'disp-x_3' displacement-x position 30.0,-10
zone history name 'disp-x_4' displacement-x position 70.0,-20.3

; initialize automatic remeshing
model remeshing on
zone remesh boundary by-slot 'Remesh'

; Target 3% Maxwell Damping in 0.35-25Hz range
zone dynamic damping maxwell 0.0245 0.35 0.021 3 0.0295 25.0

; solve for 30 seconds
model solve time 30

model save 'landslide_final'

Endnote